# Maintainer: Yaroslav de la Peña Smirnov <yps@yaroslavps.com>
# Original AUR Maintainer: Thorben Günther <echo YWRtaW5AeGVucm94Lm5ldAo= | base64 -d>
# Contributor: Drew DeVault <sir@cmpwn.com>
pkgname=mako-git
_pkgname=mako
pkgver=v1.4.1.r58.g2808b0f
pkgrel=1
license=('MIT')
pkgdesc='Lightweight notification daemon for Wayland. Package for soystemd-less systems'
makedepends=("meson" "scdoc" "libelogind" "wayland-protocols" "git")
depends=(
    "gdk-pixbuf2"
    "pango"
    "cairo"
    "elogind"
    "wayland"
)
optdepends=("jq: support for 'makoctl menu'")
arch=("x86_64")
url='http://mako-project.org'
source=("${pkgname%-*}::git+https://github.com/emersion/mako.git")
sha1sums=('SKIP')
provides=('mako')
conflicts=('mako')

pkgver() {
    cd "$_pkgname"
    (
        set -o pipefail
        git describe --long 2> /dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
            printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
    )
}

build() {
    cd "$_pkgname"
    meson build
    ninja -C build
}

package() {
    cd "$_pkgname"
    DESTDIR="$pkgdir/" ninja -C build install
    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/"${pkgname%-*}"/LICENSE
}