From d66602c360bc60a61107723eb2c88f67fc871ca5 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Yaroslav=20de=20la=20Pe=C3=B1a=20Smirnov?=
 <yps@yaroslavps.com>
Date: Sun, 5 Feb 2023 23:50:45 +0300
Subject: init

---
 .SRCINFO | 27 +++++++++++++++++++++++++++
 PKGBUILD | 55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 .SRCINFO
 create mode 100644 PKGBUILD

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 0000000..ef0271b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,27 @@
+pkgbase = rofi-lbonn-yarps
+	pkgdesc = A window switcher, application launcher and dmenu replacement (Wayland fork)
+	pkgver = 1.7.3+wayland1
+	pkgrel = 1
+	url = https://github.com/lbonn/rofi
+	arch = x86_64
+	license = MIT
+	checkdepends = ttf-font
+	makedepends = check
+	makedepends = meson
+	makedepends = wayland-protocols
+	makedepends = git
+	depends = libxdg-basedir
+	depends = startup-notification
+	depends = libxkbcommon-x11
+	depends = xcb-util-wm
+	depends = xcb-util-xrm
+	depends = librsvg
+	depends = wayland
+	depends = xcb-util-cursor
+	optdepends = i3-wm: use as a window switcher
+	provides = rofi
+	conflicts = rofi
+	source = rofi::git+https://github.com/lbonn/rofi.git#branch=wayland
+	sha256sums = SKIP
+
+pkgname = rofi-lbonn-yarps
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..4264a2b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,55 @@
+# Maintainer: Carson Rueter <swurl at swurl dot xyz>
+# Contributor: tinywrkb <tinywrkb@gmail.com>
+# Contributor: Morten Linderud <foxboron@archlinux.org>
+# Contributor: Maxim Baz <rofi at maximbaz dot com>
+# Contributor: Anatol Pomozov
+# Contributor: Benjamin Chrétien <chretien + aur [at] lirmm [dot] fr>
+# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
+# Contributor: Rasi <rasi@xssn.at>
+# Contributor: Sean Pringle <sean.pringle@gmail.com>
+# Contributor: SanskritFritz (gmail)
+
+_gitname=rofi
+pkgname=rofi-lbonn-yarps
+pkgver=1.7.3+wayland1
+_pkgver="${pkgver/_/-}"
+pkgrel=1
+pkgdesc='A window switcher, application launcher and dmenu replacement (Wayland fork)'
+arch=(x86_64)
+url="https://github.com/lbonn/$_gitname"
+license=(MIT)
+depends=(libxdg-basedir startup-notification libxkbcommon-x11 xcb-util-wm xcb-util-xrm librsvg wayland xcb-util-cursor)
+makedepends=(check meson wayland-protocols git)
+checkdepends=(ttf-font)
+optdepends=('i3-wm: use as a window switcher')
+provides=(rofi)
+conflicts=(rofi)
+source=("${_gitname}::git+${url}.git#branch=wayland")
+sha256sums=('SKIP')
+
+prepare() {
+  cd $_gitname
+  git checkout ${_pkgver}
+  git submodule update --init
+}
+
+build() {
+  arch-meson \
+    -Dwayland=enabled \
+    -Dcheck=enabled \
+    $_gitname build
+  meson compile -C build
+}
+
+check() {
+  LC_ALL=C meson test -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+
+  cd $_gitname
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+  install -dm755 "$pkgdir/usr/share/doc/$_gitname/examples"
+  install -Dm755 Examples/*.sh "$pkgdir/usr/share/doc/$_gitname/examples"
+}
-- 
cgit v1.2.3