PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Yaroslav de la Peña Smirnov <yps@yaroslavps.com>

pkgname=waybar-mpris-yarps-git
_pkgname=waybar-mpris
pkgver=r57.6bb667a
pkgrel=1
pkgdesc='MPRIS2 waybar component'
arch=('any')
url="https://git.yaroslavps.com/waybar-mpris"
license=('unknown')
provides=('waybar-mpris')
conflicts=('waybar-mpris' 'waybar-mpris-git')
depends=('glibc')
makedepends=('go' 'git')
source=(git+$url)
md5sums=(SKIP)

pkgver() {
    cd "${_pkgname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export CGO_LDFLAGS="${LDFLAGS}"
    export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"

    cd "$_pkgname"
    go build
}

package() {
    cd "$_pkgname"
    install -vDm 755 $_pkgname "$pkgdir/usr/bin/$_pkgname"
}